createAgent

Description

Creates an agent of the given type. An agent does not have a group or leader or the standard soldier FSM associated with it - for instance, an enemy soldier spawned as an agent has limited AI and will do nothing when fired upon - which can be useful to limit the amount of AI processing being done in a mission with very large numbers of "AI". Animals are also commonly created as agents.

Note

• Players assigned to an agent using selectPlayer will be able to control the agent, operate weapons and other actions, but will not be able to access their inventory using the gear screen.
• To create objects of type "Logic", use createUnit.

Syntax

createAgent [type, position, markers, placement, special]

Parameters:

• type: String - class from CfgVehicles

• position: Object or PositionAGL or Position2D - desired placement position

• markers: Array of Strings - if the markers array contains any markers, the position is randomly picked from array of given markers plus desired placement position. If any of the markers were given z coordinate with setMarkerPos, the vehicle will also be created at given z coordinate.

• placement: Number - placement radius, the unit is randomly place in a circle with this radius

• special: String - one of:

  • "NONE" - will look for a suitable empty position near given position (subject to other placement params) before creating the agent
  • "CAN_COLLIDE" - creates the agent at given position (subject to other placement params), without checking if others objects can cross its 3D model

Returns: Object

Examples

Example 1

private _agent = createAgent ["B_Soldier_F", getPosATL player, [], 0, "NONE"];

Example 2

private _agent = createAgent ["Snake_random_F", ASLToAGL getPosASL player, [], 0, "CAN_COLLIDE"]; // Creates a snake at player's feet

See also

agent · agents · isAgent · forEachMemberAgent · execFSM · BIS_fnc_execFSM

tr = createTrigger ["EmptyDetector", player modelToWorld [0, 10, 0]];
tr setTriggerArea [5, 5, 0, true];
tr setTriggerActivation ["CIV", "PRESENT", true];
rabbits = [];
private "_r";
for "_i" from 1 to 10 do {
    _r = createAgent ["Rabbit_F", position tr, [], 0, "NONE"];
    _r setVariable ["BIS_fnc_animalBehaviour_disable", true];
    rabbits pushBack _r;
};
tr setTriggerStatements [
    "if (rabbits isEqualTo thisList) exitWith {
        _r = thisList select floor random count thisList;
        _r moveTo (_r modelToWorld [2.5 - random 5, 2.5 - random 5, 0]);
    };
    _esc = rabbits - thisList;
    doStop _esc;
    {_x moveTo position thisTrigger} forEach _esc;
    systemChat str [time, _esc];
    false",
    "",
    ""
];