attachTo

Some objects you cannot attach anything to. To be more precise, you can attach objects to them, but the behaviour is unexpected. For instance:

SuitcaseObject attachTo [FoldingTableObject, [0,0,0]];

You would expect the suitcase to jump to the pivot point of the table, and stick to it.
Instead, the suitcase will freeze in it is original position. Even if the table is moved, the suitcase will be unaffected: it will not follow the table, it will not even respond to actions it reacted to prior to being attached: pushing, being shot at, etc.. It's just an object frozen in space. In MP it is even weirder, the suitcase would turn invisible.
Dodgy objects when it comes to attaching things to them: most in Objects (small), Objects (signs), all of Objects (helpers) categories, etc.

If you attach an explosive charge to an object (e.g. ammobox), the charge will not detonate when you simply set the damage to 1. You must detach it before.

private _target = myAmmoBox;
// create and attach charge
private _charge = "DemoCharge_Remote_Ammo_Scripted" createVehicle position player;
_charge attachTo [_target, [0, 0, 0.2]];
_charge setVectorDirAndUp [[0.5,0.5,0], [-0.5,0.5,0]];
// now detonate charge
detach _charge; // Important!
_charge setDamage 1;

attachTo overwrites setVectorDirAndUp if attached obj was changed to attach another one.

_obj attachTo [_logic,[0, 0, 0]];
_obj setVectorDirAndUp [[0, 1, 0], [0, 0, -1]];
_obj attachTo [_logic, [0, 0, 2]];        // vector no changes
_obj attachTo [_anotherOne, [0, 0, 0]];    // vector changes to default

Attaching an object does not update the accessibility of a place for the AI. The command should not be used for positioning large static objects - the AI will simply walk through such objects.

Using attachTo with objects that have ragdoll physics (such as ammo boxes, containers, etc.) may cause unexpected behaviour. When you do so, if the attached object intersect origin object, origin object may gain some enormous collision properties even if the collision model for the attached object is not present localy to origin object, until detached. Vehicles may start flipping with no mass calculation (ie tank might fly), player object might gain infinite Z-vector velocity on any interaction with terrain relief and other objects.

When attaching a unit which is playing an animation to a static object, the animation becomes laggy. Presumably because the update frequency of the static object is used.

To find all selection names of vehicle turrets for attachTo, you can use this script:

params ["_veh"];
private _turretSels = [];

isNil { // make sure the code runs unscheduled
    private _cfg = configOf _veh;
    _veh = createSimpleObject [getModelInfo _veh # 1, [0,0,0]]; // create a simple object instead of the actual vehicle
    deleteVehicle _veh; // mark it for deletion in the next frame

    private _turrets = configProperties [_cfg >> "Turrets", "isClass _x", true];

    private _getSelections = {_veh selectionNames "memory" apply {[_x, _veh selectionPosition [_x, "memory"], _veh selectionVectorDirAndUp [_x, "memory"]]}};
    private _allSelections = call _getSelections;

    {
        private _gun = getText (_x >> "gun");
        _veh animate [_gun, 0.4, true];
        private _newSels = call _getSelections;
        _turretSels append (_newSels - _allSelections);
        _veh animate [_gun, 0, true];
    } forEach _turrets;
};

_turretSels = _turretSels apply { _x # 0 };
_turretSels arrayIntersect _turretSels

Just pass your vehicle to this code, for example, like this:

[myVehicle] call MY_fnc_getTurretSelections; // MY_fnc_getTurretSelections is the above function

If you simply need the end point of the gun(s), use this code instead:

params ["_veh"];
configProperties [configOf _veh >> "Turrets", "isClass _x", true] apply { getText (_x >> "gunBeg") };