private

Description

Sets a variable to the innermost scope. See also param and params.

Warning

• private variables must start with an underscore: private _myVar1 = "myVar"; - see Identifier.
• Always make your local variables private (through private or params) in order to avoid overwriting a local variable of the same name.

Syntax

Syntax 1

private variableName

Parameters:

• variableName: String - e.g "_myVar"

Returns: Nothing

Syntax 2

private variableNameList

Parameters:

• variableNameList: Array of Strings - e.g ["_target", "_damage"]

Returns: Nothing

Syntax 3

since arma3 1.54

private _identifier = value

From Arma 2 v1.00 to Arma 3 v1.52: see local

Parameters:

• _identifier: underscored variable name, for example _myVar
• value: Anything: value to assign to the variable

Returns: Nothing

Examples

Example 1

private _varname = "this is my new variable"; // since Arma 3 v1.54

// identical, but less performant
private "_varname";
_varname = "this is my new variable";

Example 2

private ["_varname1", "_varname2"];
_varname1 = "variable 1";
_varname2 = "variable 2";

Example 3

_lol = 123; call { hint str [_lol] }; // [123]
_lol = 123; call { private "_lol"; hint str [_lol] }; // [any]

Example 4

_myvar = 123;
systemChat str [_myvar];        // [123]
call {
    systemChat str [_myvar];    // [123]
    private "_myvar";
    systemChat str [_myvar];    // [any]
    _myvar = 345;
    systemChat str [_myvar];    // [345]
};
systemChat str [_myvar];        // [123]

See also

param · params · privateAll

_a = 2;

_a = 1;
call compile preprocessFileLineNumbers "script2.sqf";
hint format ["%1", _a];