Post Process Effects

Scripting Commands

• ppEffectCreate
• ppEffectAdjust
• ppEffectEnable
• ppEffectEnabled
• ppEffectForceInNVG
• ppEffectCommit
• ppEffectCommitted
• ppEffectDestroy

Usage

Effect Creation

_handle = ppEffectCreate ["effect_type", priority];
_handlesArray = ppEffectCreate [["effect_type0", priority0], ["effect_type1", priority1], /* ... */];

Effect Cancellation

ppEffectDestroy handle;
ppEffectDestroy handlesArray;

Effect Disabling

Compared to the effect cancellation, in this case the effect is just disabled but still exists

_handle ppEffectEnable false;

Effect Fade out

Rather than disabling the effect completely at once, it is possible to use ppEffectAdjust to fade it out over time

//after having created and used effect:
//set the parameters for the effect back to the default values
"colorCorrections" ppEffectAdjust [1,1,0,[0,0,0,0],[1,1,1,1],[0.299, 0.587, 0.114, 0],[-1,-1,0,0,0,0,0]];
//then commit and fade out over given time (10 seconds)
"colorCorrections" ppEffectCommit 10;
//Disable completely after fadeout
"colorCorrections" ppEffectEnable false;

Parameter Setup

handle ppEffectAdjust [par0, par1, /* ... */, parN];

Parameter application

handle ppEffectCommit _duration;
handlesArray ppEffectCommit _duration;

Effect Permission

handle ppEffectEnable _OnOrOff;
handlesArray ppEffectEnable _OnOrOff;

Check if Enabled (Arma 3 v1.56)

ppEffectEnabled handle;

Example

_handle = ppEffectCreate ["colorCorrections", 1501];
_handle ppEffectEnable true;
_handle ppEffectAdjust [1.0, 1.0, 0.0, [1.0, 0.1, 1.0, 0.75], [0.0, 1.0, 1.0, 1.0], [0.199, 0.587, 0.114, 0.0]];
_handle ppEffectCommit 0;
sleep 10;
ppEffectDestroy _handle;

Table of Priorities

Priority defines sequence in which post effects are applied. The higher priority, the later the effect will be applied, on top of the others.

Parameters of Individual Effects

RadialBlur

Title: "RadialBlur"; Base Priority: 100

Note

RadialBlur will not do anything if RADIAL BLUR is disabled in Video Options

Syntax:

_radialBlurHandle ppEffectAdjust [powerX, powerY, offsetX, offsetY];

Defaults:

_radialBlurHandle ppEffectAdjust [0.01, 0.01, 0.06, 0.06];

Example:

["RadialBlur", 100, [100, 0.5, 0.1, 0.5]] spawn
{
    params ["_name", "_priority", "_effect", "_handle"];
    while {
        _handle = ppEffectCreate [_name, _priority];
        _handle < 0
    } do {
        _priority = _priority + 1;
    };
    _handle ppEffectEnable true;
    _handle ppEffectAdjust _effect;
    _handle ppEffectCommit 5;
    waitUntil { ppEffectCommitted _handle };
    systemChat "admire effect for a sec";
    uiSleep 3;
    _handle ppEffectEnable false;
    ppEffectDestroy _handle;
};

ChromAberration

Title "ChromAberration"; Base Priority: 200

Syntax:

_chromaticAberrationHandle ppEffectAdjust [aberrationPowerX, aberrationPowerY, aspectCorrection];

Defaults:

_chromaticAberrationHandle ppEffectAdjust [0.005, 0.005, false];

Example:

["ChromAberration", 200, [0.05, 0.05, true]] spawn {
    params ["_name", "_priority", "_effect", "_handle"];
    while {
        _handle = ppEffectCreate [_name, _priority];
        _handle < 0
    } do {
        _priority = _priority + 1;
    };
    _handle ppEffectEnable true;
    _handle ppEffectAdjust _effect;
    _handle ppEffectCommit 5;
    waitUntil { ppEffectCommitted _handle };
    systemChat "admire effect for a sec";
    uiSleep 3;
    _handle ppEffectEnable false;
    ppEffectDestroy _handle;
};

WetDistortion

Title: "WetDistortion"; Base Priority: 300

Note

Effect cancels automatically under water.

Syntax:

_wetDistorsionHandle ppEffectAdjust [
    value,
    top, bottom,
    horizontal1, horizontal2, vertical1, vertical2,
    horizontal1, horizontal2, vertical1, vertical2,
    randX, randY, posX, posY
];

Defaults:

_wetDistorsionHandle ppEffectAdjust [
    1,
    1, 1,
    4.10, 3.70, 2.50, 1.85,
    0.0054, 0.0041, 0.0090, 0.0070,
    0.5, 0.3, 10.0, 6.0
];

Example:

["WetDistortion", 300, [1, 0, 1, 4.10, 3.70, 2.50, 1.85, 0.0054, 0.0041, 0.05, 0.0070, 1, 1, 1, 1]] spawn
{
    params ["_name", "_priority", "_effect", "_handle"];
    while {
        _handle = ppEffectCreate [_name, _priority];
        _handle < 0
    } do {
        _priority = _priority + 1;
    };
    _handle ppEffectEnable true;
    _handle ppEffectAdjust _effect;
    _handle ppEffectCommit 5;
    waitUntil { ppEffectCommitted _handle };
    systemChat "admire effect for a sec";
    uiSleep 3;
    _handle ppEffectEnable false;
    ppEffectDestroy _handle;
};

ColorCorrections

Title: "ColorCorrections"; Base Priority: 1500

Syntax:

_colorCorrectionHandle ppEffectAdjust
[
    brightness,
    contrast,
    offset,
    [blendR, blendG, blendB, blendA],
    [colorizeR, colorizeG, colorizeB, colorizeA],
    [weightR, weightG, weightB, 0],
    [a, b, angle, cx, cy, innerRCoef, interpCoef]
];

_colorCorrectionHandle ppEffectAdjust
[
    brightness,
    contrast,
    offset,
    [blendR, blendG, blendB, blendA],
    [colorizeR, colorizeG, colorizeB, colorizeA],
    [weightR, weightG, weightB, 0]
];

Defaults:

_colorCorrectionHandle ppEffectAdjust
[
    1,
    1,
    0,
    [0, 0, 0, 0],
    [1, 1, 1, 1],
    [0.299, 0.587, 0.114, 0],
    [-1, -1, 0, 0, 0, 0, 0]
];

_colorCorrectionHandle ppEffectAdjust
[
    1,
    1,
    0,
    [0, 0, 0, 0],
    [1, 1, 1, 1],
    [0.299, 0.587, 0.114, 0]
];

Example:

["ColorCorrections", 1500, [1, 0.4, 0, [0, 0, 0, 0], [1, 1, 1, 0], [1, 1, 1, 0]]] spawn
{
    params ["_name", "_priority", "_effect", "_handle"];
    while {
        _handle = ppEffectCreate [_name, _priority];
        _handle < 0
    } do {
        _priority = _priority + 1;
    };
    _handle ppEffectEnable true;
    _handle ppEffectAdjust _effect;
    _handle ppEffectCommit 5;
    waitUntil { ppEffectCommitted _handle };
    systemChat "admire effect for a sec";
    uiSleep 3;
    _handle ppEffectEnable false;
    ppEffectDestroy _handle;
};

DynamicBlur

Title: "DynamicBlur"; Base Priority: 400

Syntax:

_dynamicBlurHandle ppEffectAdjust [value];

Defaults:

_dynamicBlurHandle ppEffectAdjust [0];

Example:

["DynamicBlur", 400, [10]] spawn
{
    params ["_name", "_priority", "_effect", "_handle"];
    while {
        _handle = ppEffectCreate [_name, _priority];
        _handle < 0
    } do {
        _priority = _priority + 1;
    };
    _handle ppEffectEnable true;
    _handle ppEffectAdjust _effect;
    _handle ppEffectCommit 5;
    waitUntil { ppEffectCommitted _handle };
    systemChat "admire effect for a sec";
    uiSleep 3;
    _handle ppEffectEnable false;
    ppEffectDestroy _handle;
};

FilmGrain

Title: "FilmGrain"; Base Priority: 2000

Note

Arma 3: In Arma 3 the monochromatic parameter is numeric. Use 0 for monochrome, any other value for colour.

Number of parameters is flexible: it may be defined from 1 to 6 parameters, meaning of individual parameters is following:

Syntax:

_filmGrainHandle ppEffectAdjust [
    intensity,
    sharpness,
    grainSize,
    intensityX0,
    intensityX1,
    monochromatic
];

Defaults:

_filmGrainHandle ppEffectAdjust [
    0.005,
    1.25,
    2.01,
    0.75,
    1.0,
    0
];

_filmGrainHandle ppEffectAdjust [
    0.005,
    1.25,
    2.01,
    0.75,
    1.0,
    true
];

Example:

["FilmGrain", 2000, [1, 0.15, 7, 0.2, 1.0, 0]] spawn
{
    params ["_name", "_priority", "_effect"];

    private _handle = -1;
    while {
        _handle = ppEffectCreate [_name, _priority];
        _handle < 0;
    } do {
        _priority = _priority + 1;
    };
    _handle ppEffectEnable true;
    _handle ppEffectAdjust _effect;
    _handle ppEffectCommit 5;
    waitUntil { sleep 0.1; ppEffectCommitted _handle };
    systemChat "admire effect for a sec";
    uiSleep 3;
    _handle ppEffectEnable false;
    ppEffectDestroy _handle;
};

["FilmGrain", 2000, [1, 0.15, 7, 0.2, 1.0, true]] spawn
{
    local _name = _this select 0;
    local _priority = _this select 1;
    local _effect = _this select 2;
    local _handle = -1;
    while {
        _handle = ppEffectCreate [_name, _priority];
        _handle < 0;
    } do {
        _priority = _priority + 1;
    };
    _handle ppEffectEnable true;
    _handle ppEffectAdjust _effect;
    _handle ppEffectCommit 5;
    waitUntil { sleep 0.1; ppEffectCommitted _handle };
    systemChat "admire effect for a sec";
    uiSleep 3;
    _handle ppEffectEnable false;
    ppEffectDestroy _handle;
};

ColorInversion

Title: "ColorInversion"; Base Priority: 2500

Syntax:

_colorInversionHandle ppEffectAdjust [Red, Green, Blue];

Defaults:

_colorInversionHandle ppEffectAdjust [0, 0, 0];

Example:

["ColorInversion", 2500, [0.5, 0.5, 0.5]] spawn
{
    params ["_name", "_priority", "_effect", "_handle"];
    while {
        _handle = ppEffectCreate [_name, _priority];
        _handle < 0
    } do {
        _priority = _priority + 1;
    };
    _handle ppEffectEnable true;
    _handle ppEffectAdjust _effect;
    _handle ppEffectCommit 5;
    waitUntil { ppEffectCommitted _handle };
    systemChat "admire effect for a sec";
    uiSleep 3;
    _handle ppEffectEnable false;
    ppEffectDestroy _handle;
};

SSAO (Arma 3 v0.50)

Title: "SSAO"; Base Priority: 0

Syntax:

_ssaoHandle ppEffectAdjust [
    intensity,
    threshold0,
    threshold1,
    nearRadius,
    farRadius,
    nearDist,
    farDist,
    depthBlurDist,
    blurPasses,
    halfRes,
    blurHalfRes
];

Defaults:

_ssaoHandle ppEffectAdjust [0, 0, 0, 0, 0, 0, 0, 0, 0, false, false];

Example:

["SSAO", 1, [3, 0.25, 0.75, 5, 50, 5, 25, 100, 3, true, true]] spawn
{
    params ["_name", "_priority", "_effect", "_handle"];
    while {
        _handle = ppEffectCreate [_name, _priority];
        _handle < 0;
    } do {
        _priority = _priority + 1;
    };
    _handle ppEffectEnable true;
    _handle ppEffectAdjust _effect;
    _handle ppEffectCommit 5;
    waitUntil { ppEffectCommitted _handle };
    systemChat "admire effect for a sec";
    uiSleep 3;
    _handle ppEffectEnable false;
    ppEffectDestroy _handle;
};

Resolution (Arma 3 v2.10)

Title: "Resolution"; Base Priority: 0

Syntax:

_resolutionHandle ppEffectAdjust [verticalResolution];

Defaults:

_ssaoHandle ppEffectAdjust [-1];

Example:

["Resolution", 1, [400]] spawn
{
    params ["_name", "_priority", "_effect", "_handle"];
    while {
        _handle = ppEffectCreate [_name, _priority];
        _handle < 0;
    } do {
        _priority = _priority + 1;
    };
    _handle ppEffectEnable true;
    _handle ppEffectAdjust _effect;
    _handle ppEffectCommit 5;
    waitUntil { ppEffectCommitted _handle };
    systemChat "admire effect for a sec";
    uiSleep 3;
    _handle ppEffectEnable false;
    ppEffectDestroy _handle;
};

Sharpness (Arma 3 v2.20)

Title: "Sharpness"; Base Priority: 0

DepthOfField (Arma 3 v2.20)

Title: "DepthOfField"; Base Priority: ?

TBD

FishEye (Arma 3 v2.20)

Title: "FishEye"; Base Priority: ?

TBD

Advanced effects

Important

The advanced effects are not intended to be used by the end user. They cannot be created by ppEffectCreate and their adjustments (via ppEffectAdjust) are immediate and do not require ppEffectCommit.
More info on the forums.

LightShafts

Title: "LightShafts"; Base Priority: N/A

• can be used with ppEffectAdjust
• can be used with ppEffectEnable
• cannot be used with ppEffectCreate
• cannot be used with ppEffectCommit

Syntax:

"LightShafts" ppEffectAdjust [sunInnerRadius, sunOuterRadius, exposure, decay];

Defaults:

"LightShafts" ppEffectAdjust [0.01, 0.6, 0.45, 0.89];

Example:

0 spawn
{
    "LightShafts" ppEffectEnable true;
    "LightShafts" ppEffectAdjust [0.1,0.25,0.1,1];
    systemChat "admire effect for a sec";
    uiSleep 3;
    "LightShafts" ppEffectEnable false;
};

HBAOPlus

Important

HBAOPlus requires DirectX 11 feature level 11 or above as well as being enabled in Video Options to affect display.

Title: "HBAOPlus"; Base Priority: N/A

• can be used with ppEffectAdjust
• cannot be used with ppEffectEnable
• cannot be used with ppEffectCreate
• cannot be used with ppEffectCommit

Syntax:

"HBAOPlus" ppEffectAdjust [radius, bias, detailAO, coarseAO, powerExponent, blurRadius, blurSharpness, fadeSharpness, foregroundViewDepth, backgroundViewDepth];

Defaults - depend on HBAO+ setting in Video Options:

// HBAO+ Soft
"HBAOPlus" ppEffectAdjust [1.0, 0.3, 0.1, 0.50, 3.0, 1.0, 4.0, 5.0, 2.0, 0.0];

// HBAO+ Medium
"HBAOPlus" ppEffectAdjust [1.0, 0.3, 0.3, 0.75, 3.0, 1.0, 4.0, 5.0, 2.0, 0.0];

// HBAO+ Strong
"HBAOPlus" ppEffectAdjust [1.2, 0.3, 0.5, 1.0, 3.0, 1.0, 4.0, 5.0, 2.0, 0.0];

Example:

0 spawn
{
    "HBAOPlus" ppEffectAdjust [2, 0.3, 1, 1, 2, 1, 4, 5, 2, 0];
    systemChat "admire effect for a sec";
    uiSleep 3;
    "HBAOPlus" ppEffectAdjust [1.0, 0.3, 0.1, 0.50, 3.0, 1.0, 4.0, 5.0, 2.0, 0.0];
};