Arma 3: Animated Opening

The Animated Opening framework allows you to easily create campaign openings by animating pictures using a timeline.

Features

• Easy to setup
• Timeline based
• Can be easily synced to music or dialogues using the timeline
• Skippable

Functionality

The framework provides the designer with simple ways to manage picture and texts and to quickly animate them efficiently. The framework also lets you organize pictures and text in layers so that you can easily manage which pictures stay on top on which stay on the bottom. It provides several ways to animate pictures: scaling, moving, rotating, blinking/pulsing and fading.

Systems

BIS_fnc_AnimatedOpening

• Enhanced version of the BIS_fnc_eventTimeline function
• Sets up the opening
  • Initializes the animatedScreen function
  • Creates the initial black out
  • starts the event timeline by calling BIS_fnc_eventTimeline function
  • holdKey setup (for skipping the opening)

Parameters

BIS_fnc_eventTimeline

• Essential system of the Animated Briefings, but the function can be used for different purposes
• It executes the code fragments at given time (keyframes)
• It can play the events from start or from a defined position (index)
• It can be interrupted from outside
• user defined code can be executed onInterrupt or onFinished

Parameters

BIS_fnc_animatedScreen

• Handles pictures, texts, layers, animations
• Provides ways to create, destroy, reset all layers
• Can animate pictures and texts in several ways (scaling, moving, rotating, etc...)
• Operates in different ways depending on which parameters are passed

NOTE: The suggested picture size is 2048x2048. This is to make sure it fits and looks sharp on different aspect ratios and resolutions.

Init mode

Reset mode

Layer Create mode

Layer Animate mode

Layer Rotate mode

Layer Fade mode

Layer Pulse mode

Text Create mode

Text Animate mode

Create Overlay mode

Create Skybox mode

Important

The suggested picture size for skybox textures is 4096x4096. This is because the texture is usually scaled to make sure that all the screen space is covered during the translating animation.

Destroy mode

BlackOut mode

BlackIn mode

Setup and Usage

Setup

A Timeline needs to be prepared before calling the Animated Opening function.

Timeline

• A timeline is a multi-dimensional array in which each element consists of a time (represented by a number) and an event (a piece of code).
• The timeline starts counting from 0 when it is created.
• When the time specified in a timeline's element has elapsed, its relative event is spawned.
• The timeline stops once it reaches the last element. The last element's code can also be empty if you're just using the element as an ending point.
• The timeline can be kept in a separate file and included using #include "timelineFile.sqf"; within the file calling the animated opening.

private _timeline =
[
    [
        0,
        {
            [MODE_RESET, [true, true]]    call BIS_fnc_animatedScreen;
            [MODE_BLACKIN, 0, false]    call BIS_fnc_animatedScreen;
        }
    ],
    [
        1.5,
        {
            [MODE_BLACKOUT, 3, false] call BIS_fnc_animatedScreen;
        }
    ],
    [
        8.2,
        {
            [MODE_RESET, [true, true]]    call BIS_fnc_animatedScreen;
            [MODE_BLACKOUT, 0.01, true]    call BIS_fnc_animatedScreen;

            [MODE_LAYER_CREATE,    C03_SLIDE1_ID_DUST,        C03_SLIDE1_IMG_DUST,        nil,            nil,    1.3] call BIS_fnc_animatedScreen;
            [MODE_LAYER_CREATE,    C03_SLIDE1_ID_OBSTACLE,    C03_SLIDE1_IMG_OBSTACLE,    [0.46, 0.45],    nil,    1.2] call BIS_fnc_animatedScreen;
        }
    ],
    [12, {}]
];

The Animated Opening can be started by calling the function BIS_fnc_AnimatedOpening. Once called, the opening will start right away.

// Timeline of events
private _timeline =
[
    [0.0, { hint "Start of the Timeline" }],
    [1.0, { hint "Event 1" }],
    [3.0, { hint "End of the timeline" }]
];

// Start the Animated Opening at index 0
// also start the "LeadTrack03_F_Tacops" audio track and sync the timeline to it
[_timeline, 0, "LeadTrack03_F_Tacops"] spawn BIS_fnc_animatedOpening;

// Wait until timeline is over
waitUntil { !(missionNamespace getVariable "BIS_fnc_eventTimeline_playing"); };

// End Intro and start mission
endMission "END1";

Note

• The opening can be started from a different keyframe (by passing the pointer/index), which is helpful in the development/testing phase.
• The opening can be interrupted by using the following line of code: missionNamespace setVariable ["BIS_fnc_eventTimeline_play", false]

Usage

The initialization and destruction of the framework is handled by the BIS_fnc_AnimatedOpening and you will not need to deal with that.

The function initializes the following layers:

• 15 Picture layers
• 5 Text layers
• 1 Overlay layer (used by the holdKey function to display the "Press SPACE to skip" text

To create and display a new picture, use the MODE_LAYER_CREATE code. You can then use then MODE_LAYER_ANIMATE mode to scale and translate it.

[MODE_LAYER_CREATE, C03_SLIDE1_ID_OBSTACLE, C03_SLIDE1_IMG_OBSTACLE, [0.46,0.45], nil, 1.2] call BIS_fnc_animatedScreen;
[MODE_LAYER_ANIMATE, [C03_SLIDE1_ID_OBSTACLE], 8, [0.50,0.46], 1.4] call BIS_fnc_animatedScreen;

similarly, other modes can be used to rotate or fade the image.

Important

The suggested picture size is 2048x2048 and 4096x4096 for skybox textures. This is to make sure it fits and looks sharp on different aspect ratios and resolutions.

The workflow for texts is very similar but the modes to use are different.

[MODE_TEXT_CREATE, _layer, _text, _pos, _align, COLOR_TEXT_DYNAMIC_FOREGROUND, 0, SIZE_TEXT_DYNAMIC, 0, FONT_TEXT_DYNAMIC] call BIS_fnc_animatedScreen;
[MODE_TEXT_ANIMATE, _layer, TIME_TEXT_DYNAMIC_A, nil, 0.9, 0.4, nil, 0.7, 0] call BIS_fnc_animatedScreen;

To delete displayed pictures and text, use the MODE_RESET mode.

// [true, true]: the first true reset the picture layers, the second one the text layers
[MODE_RESET, [true, true]] call BIS_fnc_animatedScreen;

Black In and Black Out modes can be used to fade to or from black.

[40.0, { [MODE_BLACKOUT, 2, false] call BIS_fnc_animatedScreen; }],
[42.0, { [MODE_BLACKIN, 0, false] call BIS_fnc_animatedScreen; }]

To create an animated skybox-like background use MODE_SKYBOX_CREATE which adds and animates the texture.

[MODE_SKYBOX_CREATE, C03_SLIDE2_ID_CLOUDS, C03_SLIDE2_IMG_CLOUDS,nil, 45] call BIS_fnc_animatedScreen;

Synchronizing music to timeline events

See the Animated Briefing page for more information about the suggested workflow.