addPublicVariableEventHandler

Broken
Global argument
Local effect
Arma 3 v0.50
First in Armed Assault v1.09

Command · also in Event Handlers, Multiplayer, Variables · Markdown · JSON · original wiki page

Warning
This command is listed as broken on the wiki. Use remoteExec or remoteExecCall instead.

Description

Note
This command is deprecated since Arma 3 v1.52 and the introduction of remoteExec and remoteExecCall.

This event handler will detect if a missionNamespace variable (it is attached to) has been broadcast over network with publicVariable, publicVariableClient or publicVariableServer commands and will execute EH code upon detection.

Note

This EH works only in Multiplayer environment

There is no way to remove this EH

This EH will not fire on the machine that executed broadcast with publicVariable command, only on the machines that receive the broadcast

The value of broadcast variable can be exactly the same, it is the actual broadcast that triggers EH not the change in variable

Syntax

Syntax 1

varName addPublicVariableEventHandler code

Parameters:

varName: String - missionNamespace variable name
code: Code - by default, the code is executed in missionNamespace. _this arguments array is in format [varName, value, target]:
- varName: String - broadcast variable name (same variable name EH is attached to)
- value: Anything - broadcast variable value
- target: Object or Group - target the variable got set on with setVariable (see Alternative Syntax)

Returns: Nothing

Syntax 2

since arma3 1.46

varName addPublicVariableEventHandler [target, code]

Parameters:

varName: String - name of the variable set on target with setVariable
target: Object, Group or Team Member
code: Code

Returns: Nothing

Examples

Example 1

"publicThis" addPublicVariableEventHandler {
    _varName = _this select 0;
    _value = _this select 1;
    _target = _this select 2;
    hint format ["%1 has been updated to %2 for %3", _varName, _value, target];
};

Example 2

Client:

"'^:)123BURP,+=lol" addPublicVariableEventHandler {hint ("NUTS are " + (_this select 1))};

Server:

missionNamespace setVariable ["'^:)123BURP,+=lol", "craZZZZy"];
publicVariable "'^:)123BURP,+=lol";

Problems

Warning
The Alternative Syntax does not work as intended.

Community notes

TeRp

2007-12-22

Please note that varName indicates which variable you want to monitor with this eventhandler.
As a result, the example eventhandler on this page will only fire when the variable publicThis has been changed, but not if any other variable was changed by any other client via the publicVariable command.

MulleDK13

2014-02-27

Note on using addPublicVariableEventHandler during initialization: If you need a function to call addPublicVariableEventHandler during initialization, you must use postInit. addPublicVariableEventHandler does not work during preInit.

Killzone_Kid

2014-02-27

MulleDK13's note above needs some clarification. You don't "must" use postInit and you absolutely can use preInit function to initialise addPublicVariableEventHandler if you start scheduled script from it.

// script with preInit = 1; in CfgFunctions
0 spawn {
    "someVar" addPublicVariableEventHandler {
        // yourcode
    };
};

SilentSpike

2015-11-23

While it is true that the event handler will only fire on the machine receiving the broadcast value, please note that this machine can actually be the same machine broadcasting it in the cases of publicVariableClient and publicVariableServer.

Examples:

if (isServer) then
{
    "OnServer" addPublicVariableEventHandler { hint "This event handler still fired!"; };
    publicVariableServer "OnServer";
};

// This example assumes the client knows their own client ID
// It does also work on the server (when the server ID is used) irrespective of the command name

"OnClient" addPublicVariableEventHandler { hint "This event handler still fired!"; };
clientID publicVariableClient "OnClient";