moveInTurret

Local argument
Global effect
Arma 3 v0.50
First in Armed Assault v1.00

Command · Markdown · JSON · original wiki page

Description

Moves the soldier into the vehicle's turret. (Immediately, without animation).

Note
See AI Group Vehicle Management for more information.

Important
If the unit is already in a vehicle, nothing will happen. You should use moveOut to move the unit out of his vehicle before trying to move him into a new (or same) vehicle.

Syntax

unitName moveInTurret [vehicle, turretPath]

Parameters:

unitName: Object
vehicle: Object
turretPath: Turret Path

Returns: Nothing

Examples

Example 1

_soldierOne moveInTurret [_tank, [0, 0]];

Community notes

Kronzky

2008-03-06

To find out which turrets are available on a vehicle (edit: before allTurrets), and what the syntax is, you can use this little script.

hcpookie

2014-02-13

Examples for nested turrets:

MainTurret =

_soldierOne moveInTurret [_tank, [0]];

CommanderTurret =

_soldierOne moveInTurret [_tank, [0, 0]];

... where:

MainTurret is the standard BIS MainTurret... e.g:

class Turrets
{
    class MainTurret {};
};

CommanderTurret is the standard BIS CommanderTurret located on the MainTurret... e.g:

class Turrets
{
    class MainTurret
    {
        class Turrets
        {
            class CommanderTurret {};
        };
    };
};

Killzone_Kid

2014-03-19

Here is a small function to find available turret paths for a given vehicle. It will only search 2 levels deep, hence called commonTurrets:

KK_fnc_commonTurrets = {
    private ["_arr","_trts"];
    _arr = [];
    _trts = configFile / "CfgVehicles" / typeOf _this / "Turrets";
    for "_i" from 0 to count _trts - 1 do {
        _arr set [count _arr, [_i]];
        for "_j" from 0 to count (
            _trts / configName (_trts select _i) / "Turrets"
        ) - 1 do {
            _arr set [count _arr, [_i, _j]];
        };
    };
    _arr
};

Example call:

hint str (vehicle player call KK_fnc_commonTurrets); // [[0],[0,0]]