forceWeaponFire

Local argument
Global effect
Arma 3 v0.50

Command · also in Weapons · Markdown · JSON · original wiki page

Description

The unit will be forced to fire weapon from the given muzzle. The weapon will not fire if firemode passed as parameter is not supported by the given muzzle. The muzzle could belong to a vehicle weapon and unit in this case will be the unit operating this weapon. Doesnt't seem to work for units in FFV positions. Works on player. See also: BIS_fnc_fire

Syntax

unit forceWeaponFire [muzzle, firemode]

Parameters:

unit: Object - unit alone or in vehicle
muzzle: String
firemode: String - common options are "Single", "Burst", "FullAuto". For the full list of a weapon firemodes:
```
hint str (getArray (configFile >> "CfgWeapons" >> currentWeapon player >> "modes"));
```
If modes[] param in config for the weapon says {"this"}, then the same classname as for the weapon param (currentWeapon player) should be used as firemode param.

Returns: Nothing

Examples

Example 1

_unit forceWeaponFire ["arifle_MX_F", "Single"];
_unit forceWeaponFire ["hgun_ACPC2_F", "hgun_ACPC2_F"];
_unit forceWeaponFire ["HandGrenadeMuzzle","HandGrenadeMuzzle"];
_unit forceWeaponFire ["MiniGrenadeMuzzle","MiniGrenadeMuzzle"];
_unit forceWeaponFire ["HandGrenade_Stone","HandGrenade_Stone"];
_unit forceWeaponFire ["SmokeShellMuzzle","SmokeShellMuzzle"];
_unit forceWeaponFire ["ChemlightGreenMuzzle","ChemlightGreenMuzzle"];
_unit forceWeaponFire ["IRGrenade","IRGrenade"];
_unit forceWeaponFire ["Laserdesignator","Laserdesignator"];

Example 2

gunner blackfoot forceWeaponFire ["gatling_20mm", "close"];

Community notes

Killzone_Kid

2013-08-25

Here is a neat workaround trick for firemode change from a script:

_weapon = currentWeapon player;
_ammo = player ammo _weapon;
player setAmmo [_weapon, 0];
player forceWeaponFire [_weapon, "FullAuto"];
player setAmmo [_weapon, _ammo];

ffur2007slx2_5

2014-04-14

(A3 1.16) forceWeaponFire is no longer only limited to units, but can remote aircrafts weapon firing as well. Passed source unit should be the correct one who controls the weapon, if passed mode is "this", use the weapon name instead:

_weapon = (weapons _veh) select 3;
_mode = (getArray (configFile >> "cfgweapons" >> _weapon >> "modes")) select 0;
if (_mode == "this") then {_mode = _weapon;};
(driver _veh) forceWeaponFire [_weapon, _mode];
//Force a CAS fire a rocket.

Currently this command is not available for land vehicle remote fire.

Benargee

2014-09-02

Similar to Killzone_Kid's note, This fires the units current weapon in its current firemode.

_unit forceWeaponFire [weaponState _unit select 1, weaponState _unit select 2];

Killzone_Kid

2015-01-03

fireAtTarget command can be used to force fire gunner weapon in vehicles. A gunner must be present.

_veh fireAtTarget [objNull];

Will fire one shot even if player is gunner. fire command can also be used to fire vehicle weapon, like smoke launcher for example:

vehicle player fire "SmokeLauncher";

And if this doesn't work, it is possible to force fire via action

tank action ["UseWeapon", tank, commander tank, 0];