---
name: "Function"
type: topic
aliases: ["Functions - SQF", "In-line function", "Inline function", "function"]
source: https://community.bistudio.com/wiki/Function
revid: 349916
updated: 2023-11-20T22:11:06Z
---

# Function

> [!IMPORTANT]
> For a proper writing tutorial, see [Writing a Function](../topics/Writing_a_Function.md).
>
> See also:
>
> - Arma 2: Functions Library
> - Take On Helicopters: Functions Library
> - [Arma 3: Functions Library](../topics/Functions_Library.md)

A **function** contains [code](../topics/Code.md) which usually consists of an *input*, *processing* and *output* part. Functions were first introduced in the Operation Flashpoint: Resistance patch.
The main advantages of functions are:

**Improved legibility:** By writing the code once and re-using it by calling the function

**Easier debugging:** If your function contains an error, you only have to fix it in one place

### Types of function

#### Functions-as-files

*See [calling functions](../topics/Function.md#call) for how a function-as-file is called.*

Functions as files are functions stored within a file. These are usually used for larger and more complex functions. The code is evaluated in the same way, however, there are additional commands which must include the file before the function itself can be called.

```sqf
// Code inside fn_showHint.sqf
hint "Function was executed!"; // Function will show a hint when executed
```

#### Inline functions

Inline functions are functions are technically [code](../topics/Code.md) which is often stored within a variable or declared as a function parameter. Inline functions operate the same way as functions-as-files as both are evaluated in the same way, but the difference is that inline functions are stored within parentheses `{`}, whereas functions-as-files do not require these.

```sqf
// Inline function as variable
TAG_fnc_showHint =
{
    hint "Function was executed!"; // Function will show a hint when executed
};
call TAG_fnc_showHint;
```

### Anatomy of a function

When scripting, there are two types of functions: functions-as-files and inline functions.
Functions-as-files are instances where the a whole file itself is used to house a function, whereas inline functions are either contained within a variable or as a parameter of a function.
Some built-in functions require functions-as-files, whereas most will support both.

#### Parameters (input)

Parameters for functions are available to the function via the [magic variable](../topics/Magic_Variables.md) [_this](../topics/Magic_Variables.md#this).
Declaration of parameters can be done using the [params](../commands/params.md) command. Common practice for defining parameters is done via the use of [private](../commands/private.md) variables and defined variables.

```sqf
// Code inside fn_showHint.sqf
params ["_text"];
hint _text;
```

```sqf
// Inline function as variable
TAG_fnc_showHint =
{
    params ["_text"];
    hint _text;
};
```

```sqf
"Function was executed!" call TAG_fnc_showHint;
```

Parameters passed to functions are passed **before** the function, rather than after (such as the mathematical or c-like syntax *f(x)*).

```sqf
// Array variable as parameter
_myTempParams = [_parameterOne, _parameterTwo];
_myTempVariableTwo = _myTempParams call myInlineFunction;
```

```sqf
// Array as parameter
_myTempVariable = [_parameterOne,_parameterTwo] call myInlineFunction;
```

#### Return Values (output)

The value of the last executed statement in a function is returned to the calling instance.

```sqf
my_fnc = {
    if (_this > 0) exitWith {
        _this + 1
    };
    _this - 1
};

hint str ( 5 call my_fnc); //  6
hint str (-5 call my_fnc); // -6
```

In the first example "_this + 1" is the last executed statement in my_fnc, in the second example it is "_this - 1".

> [!NOTE]
> It was believed at one point that the returning statement should not have a semicolon `;` after it; this is false and having a semicolon does not change anything and is recommended.

```sqf
my_fnc = {
    a = 1;
    b = 2;
    c = a + b;
    c // ← fine
};
```

```sqf
my_fnc = {
    a = 1;
    b = 2;
    c = a + b;
    c; // ← better
};
```

More examples:

```sqf
// myCode.sqf
private _myName = _this select 0;

private _returnMe = "FAIL";

if (_myName == "Test") then
{
    _returnMe = "PASS";
};
_returnMe;
```

```sqf
// myCodeInline
myCodeReturnValue = {
    private _myName = _this select 0;
    private _returnMe = "FAIL";

    if (_myName == "Kaboom") then
    {
        _returnMe = "PASS";
    };

    _returnMe
};

_myCalledVariable = ["Kaboom"] call myCodeReturnValue; // "PASS"
_myCalledVariableFail = ["Blah"] call myCodeReturnValue; // "FAIL"
```

```sqf
// return.sqf
STATEMENT 1;
STATEMENT 2;
RETURN_VALUE
```

```sqf
// test.sqf
value = call compile preprocessFile "return.sqf";
// value is now RETURN_VALUE

call compile preprocessFile "return.sqf";
// valid, but RETURN_VALUE is not saved anywhere
```

#### Execution

Functions can be executed from several points in the game:

- Other [scripts](../topics/Script_File.md)
- Other functions
- Scripting lines in the Mission Editor
- Event Handlers in addon config files

Functions are first loaded as [String](../topics/String.md) from a file via [preprocessFile](../commands/preprocessFile.md) or [loadFile](../commands/loadFile.md). They are then executed via the [call](../commands/call.md) or [spawn](../commands/spawn.md) command. Since Armed Assault the loaded [String](../topics/String.md) needs to be [compiled](../commands/compile.md) in order to convert it to [Code](../topics/Code.md), which is required for [call](../commands/call.md) or [spawn](../commands/spawn.md).

##### Call

Example (Operation Flashpoint):

```sqf
myFunction1 = loadFile "myFunction1.sqf";
myFunction2 = preprocessFile "myFunction2.sqf";

call myFunction1;
[1, 2] call myFunction2;
```

Example (Armed Assault):

```sqf
myFunction1 = compile loadFile "myFunction1.sqf";
myFunction2 = compile preprocessFile "myFunction2.sqf";

_result1 = call myFunction1;
_result2 = [1, 2] call myFunction2;
```

Functions executed using [call](../commands/call.md) are run *within* the executing instance, which waits for the result of the function.
Unlike scripts, functions halt all other game engine processes until the function has completed its instructions.
This means functions run faster than scripts, and the result of functions is immediate and unambiguous.
It can also mean that if a function takes too long to run it will have an adverse effect on game play - large functions or CPU intensive functions can cause the game to seize up until it completes.
When creating a functions you want the function to be short and sweet to achieve the best results.

> [!NOTE]
> You can still use the special variables and commands of [scripts](../topics/Script_File.md) in functions (Armed Assault only)!

##### Spawn

Functions may also be executed using [spawn](../commands/spawn.md), but then the function result is not accessible, making it behave more like a procedure.
Spawned functions will run asynchronously or *alongside* the executing instance. This helps prevent large CPU intensive functions from seizing up the game.

Example (Armed Assault):

```sqf
myFunction1 = compile loadFile "myFunction1.sqf";
myFunction2 = compile preprocessFile "myFunction2.sqf";

_param spawn myFunction1;
[1, 2] spawn myFunction2;
```

### Examples

#### Example 1: max.sqf

In this example the function returns maximum of first and second argument.

max.sqf

```sqf
//"Return maximum of first and second argument";
params ["_a", "_b"];
[_b, _a] select (_a > _b);
```

alternative max.sqf (big boys code :))

```sqf
(_this select 0) max (_this select 1);
```

executing script:

```sqf
fMax = compile preprocessFile "max.sqf";
maxValue = [3, 5] call fMax;

// maxValue is now 5
```

#### Example 2: infantrySafe.sqf

In this example the function returns no value and switches all units to safe mode.

```sqf
// Switch all infantry units to safe mode
{
    if (vehicle _x == _x) then
    {
        _x setBehaviour "safe";
    }
} forEach _this;
```

#### Example 3: Inline Function

An inline-function can be created in any script:

```sqf
FNC_sayhello = {hint format ["hello %1", _this]};
```

This function can then be called (in other scripts, functions, unit's init lines, trigger activation fields, etc.) via:

```sqf
name player call FNC_sayhello
```

In case the function doesn't require any arguments you can just call the function.

```sqf
call FNC_helloall
```

### See also

- [Scripts](../topics/Script_File.md)
- [SQF Syntax](../topics/SQF_Syntax.md)
- [call](../commands/call.md)

<sub>Source: [BI Community Wiki — Function](https://community.bistudio.com/wiki/Function) (revision 349916).</sub>